Simulation of VerilogA model of a VCO ?

Can you share the model? The common mistake is for the phase not to be periodic, which is solvable using idtmod rather than idt - but seeing the model would really help here.

Andrew

Hi Andrew, thanks for the reply. Below given is the VerilogA model


module VCO(out_p, out_n, Vtp, Vtn, tail);

inout out_p, out_n; // Differential outputs
input Vtp, Vtn; // Differential tuning voltage

electrical out_p, out_n, Vtp, Vtn, tail;

// ============================
// Parameters
// ============================
parameter real fvco = 4.5e9; // Center frequency in Hz
parameter real Kvco = 1.0e6; // VCO gain in Hz/V
parameter real Vout_CM = 0.8; // Output common-mode voltage (V)
parameter real Avco = 0.5; // Differential peak amplitude (V)

// ============================
// Internal variables
// ============================
real freq, phase;
real Vctrl_diff;

analog begin
// Compute differential tuning voltage
Vctrl_diff = V(Vtp) - V(Vtn);

// Frequency as function of control voltage
freq = fvco + Kvco * Vctrl_diff;

// Integrate frequency to get phase (rad)
phase = 2 * `M_PI * idt(freq, 0.0);

// Output differential sine wave
V(out_p) <+ Vout_CM + Avco * sin(phase);
V(out_n) <+ Vout_CM - Avco * sin(phase);
end

endmodule

If you change the line:

phase = 2 * `M_PI * idt(freq, 0.0);

to

phase = 2 * `M_PI * idtmod(freq, 0.0, 1);

Then it will converge with PSS. The issue with the original was that the phase keeps increasing and so there's no periodic solution.

The problem, however, is that idtmod is not supported in harmonic balance. Somehow I'd not noticed that - let me do some digging (I found an internal request on this but no clear outcome).

Andrew

I'd also suggest you add:

$bound_step(1/freq/20);

to the model to force a few more time steps per period. The dynamic timestep control tends to need a bit of a clue with oscillator models as other things in the circuit may not be enough to cause the time steps to be small enough to follow the output properly.

Andrew

I'd also suggest you add:

$bound_step(1/freq/20);

to the model to force a few more time steps per period. The dynamic timestep control tends to need a bit of a clue with oscillator models as other things in the circuit may not be enough to cause the time steps to be small enough to follow the output properly.

Andrew